VB.NET 怎么读写二进制文件，类似Open

Question

可以任意选择读取位置，就像Get #1 ， 1000，byte（）一样。
也可以任意选择写入位置，就像Put #1,1000，byte（）一样。
谢谢各位大侠了

Answer 1

本示例阐释二进制文件的基本输入和输出（使用 BinaryReader、BinaryWriter 和 FileStream 类。 在如何创建日志文件标题下面有一个类似的主题。读写二进制信息使您可以创建和使用通过其他输入和输出方法无法访问的文件。本示例还展示写入非字符串数据，并展示二进制 I/O 的功能。

尽管计算机上的文件可以不同的类型和文件存储，但是，二进制格式是文件的较常用格式之一。此处对创建二进制文件的简短介绍使用基类 BinaryReader 和 BinaryWriter 从文件获取信息，并将信息放入文件。这些类中的每个类均封装一个信息流，因此，在进一步操作之前，需要创建一个可用于来回写信息的流。因为要创建文件，所以可使用 FileStream 来公开特定文件，在此情况下，如果该文件已存在，则可以修改该文件，或者如果该文件尚不存在，则可以创建该文件。在有 FileStream 之后，可以使用它来构造 BinaryReader 和 BinaryWriter

在读入信息之后，可以对信息进行所需的任何操作。但是，在某些时候，您可能想要将信息写回文件，因此需要 BinaryWriter。在本示例中，您将使用 Seek 方法将信息追加到文件结尾，因此，在开始写入之前，请确保指向文件的指针位于文件结尾。在使用 BinaryWriter 写入信息时有多个选项。因为 Write 方法有足够的重载用于您能够写入的所有信息类型，所以，可以使用 Write 方法向您的编写器封装的流写入任何标准形式的信息。本情况下，还可以使用 WriteString 方法向流中写入长度预先固定的字符串。

VB Source: VB\ReadWrite.aspx

< %@ Import Namespace="System.Text" %>
< %@ Import Namespace="System.IO" %>
< script language="VB" runat=server>
Class TestBinary
Public Shared Function ReadFile(selection As String) As String
Dim output As StringBuilder = New StringBuilder()

Dim fs As FileStream = New FileStream("data.bin", FileMode.OpenOrCreate)
Dim r As BinaryReader = New BinaryReader(fs)
Try
r.BaseStream.Seek(0,SeekOrigin.Begin) ' 将文件指针设置到文件开始
' 因为不同数据类型之间的很多转换结果都是不可解释的，
' 所以当在其他类型与二进制数据之间进行转换时，
' 必须捕捉可能引发的任何潜在的异常...
' 能够正确读取数据依赖于如何写入信息...
' 这与写日志文件时不同。
Do While r.BaseStream.Position < r.BaseStream.Length ' 当未到达文件结尾时
Select Case selection
Case "Boolean"
output.Append( r.ReadBoolean().ToString() )
Case "String"
output.Append( r.ReadString() )
Case "Integer"
output.Append( r.ReadInt32().ToString() )
End Select
Loop
Finally
fs.Close()
End Try
return output.ToString()
End Function

Public Shared Function WriteFile(output As Object, selection As String) As String
Dim fs As FileStream = New FileStream("data.bin", FileMode.Create)
Dim w As BinaryWriter = New BinaryWriter(fs)
Dim strOutput As String = ""
w.BaseStream.Seek(0, SeekOrigin.End) ' 将文件指针设置到文件结尾
' 因为正在写的信息可能不适合于所选择用于写入的特定样式
' （例如，单词“Hello”作为整数？），所以我们必须捕捉写入
' 错误，并通知用户未能执行该任务
Try
Select Case selection
Case "Boolean"
Dim b As Boolean = Convert.ToBoolean(output)
w.Write( b )
Case "String"
Dim s As String = Convert.ToString(output)
w.Write( s )
Case "Integer"
Dim i As Int32 = Convert.ToInt32(output)
w.Write(i)
End Select
Catch E As Exception
' 让用户知道未能写入该信息
strOutput = "写异常：" & chr(13) & _
"无法以所请求的格式写入要写入的信息。" & _
chr(13) & "请输入尝试写入的数据类型的有效值"
End Try
fs.Close()
return strOutput
End Function
End Class

Sub btnAction_Click(src As Object, E As EventArgs)
Dim s As String = ""
' 写出文件
s = TestBinary.WriteFile(txtInput.Text, lstDataIn.SelectedItem.Text)
If s = "" Then
Try
' 读回信息，显示信息...
txtOutput.Text = TestBinary.ReadFile(lstDataIn.SelectedItem.Text)
Catch Exc As Exception
' 让用户知道未能写入信息
s = "读异常：" & chr(13) & _
"无法以所请求的格式读取要写入的信息。" & _
chr(13) & "请输入尝试写入的数据类型的有效值"
End Try
Else
txtOutput.Text = s
End If
End Sub
< /script>

< html>
< head>
<link rel="stylesheet" href="intro.css">
< /head>
< body style="background-color:f6e4c6">
< form method=post runat="server">
< p>

< table>
< tr>
<td><b>
下面的示例使用 BinaryWriter 对象创建一个二进制文件，然后使用 BinaryReader 读取该信息。</b>可以选择不同的对象来将所需的信息写入文件

此演示用于强调您需要知道如何读取已写入的二进制文件。一旦以某种格式写入数据，就只能以该格式读取该信息。但是，可以将多种不同的数据类型写入文件。在此演示中，输入任意字符串并将它们作为字符串读取，对于整型，仅输入整型数值项（试试浮点数字，然后看看会发生什么...）；对于布尔型项，仅输入词“false”和“true”。
<p>
<hr>
</td>
< /tr>
< /table>

< asp:Table id="basetable" runat="server" border="0" cellspacing="0" cellpadding="5">

< asp:tablerow>
<asp:tablecell verticalalign="top">
请选择要保存到二进制文件的数据类型...
</asp:tablecell>
<asp:tablecell verticalalign="top">
<asp:listbox id="lstDataIn" runat="server">
<asp:listitem>Boolean</asp:listitem>
<asp:listitem selected="true">String</asp:listitem>
<asp:listitem>Integer</asp:listitem>
</asp:listbox>
</asp:tablecell>
<asp:tablecell verticalalign="top">
<asp:button id="btnAction" onclick="btnAction_Click" Text="写入/读取文件" runat="server"/>
</asp:tablecell>
< /asp:tablerow>

Answer 2

VB.Net中己不再使用Open来读写二进制文件，而是用BinaryReader/BinaryWriter来对二进制文件进行读写操作。

举例如下

Imports System.Windows.Forms
Imports System.IO
Imports System.Text

Public Class Form1

    '按下Button1按钮，创建一个二进制文件并写入一个浮点数
    Private Sub Button1_Click(sender As Object, _
                              e As EventArgs) Handles Button1.Click
        '创建文件准备写入
        Dim myFile As New IO.FileStream("d:\data.bin", _
                                        FileMode.Create, _
                                        FileAccess.Write)
        '写入二进制格式数据
        Dim bw As New BinaryWriter(myFile)
        '写入一个浮点数
        Dim f As Single
        f = 3.14159
        bw.Write(f)
        '关闭流
        bw.Flush()
        bw.Close()
        '关闭文件
        myFile.Close()
    End Sub

    '按下Button2按钮，从二进制文件并读入一个浮点数值并显示
    Private Sub Button2_Click(sender As Object, _
                              e As EventArgs) Handles Button2.Click
        
        '文件不如不存在则退出
        If Not File.Exists("d:\data.bin") Then Exit Sub
        
        '打开文件准备读
        Dim myFile As New IO.FileStream("d:\data.bin", _
                                        FileMode.Open, _
                                        FileAccess.Read)
        '按二进制格式读取数据
        Dim br As New BinaryReader(myFile)
        '读取一个浮点数
        Dim f As Single
        f = br.ReadSingle()
        '关闭流
        br.Close()
        '关闭文件
        myFile.Close()
        '显示读出的内容
        MessageBox.Show(f.ToString())
    End Sub
End Class

Answer 3

'从文件指定位置读取数据
dim fn as new io.filestream("e:\123.mp3", IO.FileMode.Open)
dim fr as new io.binaryreader(fn)
fr.BaseStream.Position = 1000 '从1000字节处开始读取文件
dim data() as byte= fr.ReadBytes(2000) '读取2000个字节至data()数组
fr.close
fn.close

'在文件指定位置写入数据
dim fn as new io.filestream("e:\123.mp3", IO.FileMode.Open)
dim fr as new io.binarywriter(fn)
fr.BaseStream.Position = 1000 '从1000字节处开始读取文件
fr.write(data) '将data数组写入文件
fr.close
fn.close

'关键在于这句：fr.BaseStream.Position = 1000 ，即将文件流的指针移动到1000字节处，然后再根据自己的要求操作即可。本回答被提问者和网友采纳

Answer 4

可以用FileFet、FilePut函数：
http://msdn.microsoft.com/en-us/library/0s9sa1ab(v=vs.71).aspx